;---------------------------------------------------------------------------;
; RS-232 Data Switch Firmware                                               ;
;                                                                           ;
; File: COMMANDS.ASM                                                        ;
;                                                                           ;
; This file contains the code for most of the commands supported by the     ;
; switch firmware.                                                          ;
;---------------------------------------------------------------------------;
 
commands segment code unit
 
                rseg    commands
 
$nolist
$include(globals.asm)
$list
 
extrn code(skipspc)
extrn code(prtstr)
extrn code(getport)
extrn code(prompt)
extrn code(matchtoken)
extrn code(getnum)
extrn code(printnum)
extrn code(tab)
extrn code(putchar)
extrn code(crlf)
extrn code(setbaud)
extrn code(fixtbl)
extrn code(toupper)
extrn code(daysthismonth)
extrn code(checkmaint)
extrn code(maskaddr)
extrn code(printhex2)
extrn code(gethex)
extrn code(download)
 
public dcd_cmd
public dtr_cmd
public break_cmd
public list_cmd
public baud_cmd
public name_cmd
public date_cmd
public mode_cmd
public mask_cmd
public auto_cmd
public help_cmd
public run_cmd
public dl_cmd
 
public inc_str
 
 
;---------------------------------------------------------------------------
; Function:  dcd_cmd
;
; Description:
;    This function provides the processing for the "dcd" command.  It sets
;    the value of the DCD/DTR output on a given port to one of the following:
;       - Forced to true
;       - Following the corresponding input on the port connected to.
;    It also sets the default value (value output when the port is not
;    connected to anything and DTR/DCD is not forced true.
;
; Command syntax: DCD SOURCE [<port>]
;                 DCD FORCE [<port>]
;                 DCD DEFAULT 0|1 [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
                ; Command may only be used in maintenance mode.
 
dcd_cmd:        lcall   checkmaint
                jz      dcd_ok
                ljmp    prompt
 
                ; Get the keyword ("SOURCE", "FORCE", or "DEFAULT").
 
dcd_ok:         lcall   skipspc
                jz      dcd_incomplete
                mov     dptr,#dcdcmdtbl
                lcall   matchtoken
                jz      dcd_syntax
                cjne    a,#3,dcd_notdef
 
                ; Process "DCD DEFAULT"
 
                ; Get the default value and ensure it is 0 or 1.
 
                lcall   skipspc
                jz      dcd_incomplete
                mov     r2,#' '
                lcall   getnum
                jb      badflag,dcd_exit
                mov     a,r1
                clr     c
                subb    a,#2
                jnc     dcd_syntax
                mov     r5,1
 
                ; Get the port number.  If not given, assume the current
                ; command port.
 
                lcall   skipspc
                jz      dcd_myport2
                lcall   getport
                jz      dcd_exit
                sjmp    dcd_gotport2
dcd_myport2:    mov     a,myport
 
                ; Make sure the port is one of the 4 for which DCD/DTR can
                ; be controlled.
 
dcd_gotport2:   mov     r0,a
                clr     c
                subb    a,#5
                jnc     dcd_toohigh
 
                ; Compute the address of the entry in the DCD/DTR default table.
 
                mov     a,r0
                dec     a
                add     a,#dtrdeftbl-256*(dtrdeftbl/256)
                mov     dpl,a
                clr     a
                addc    a,#dtrdeftbl/256
                mov     dph,a
 
                ; Store the default in the table and exit.
 
                mov     a,r5
                movx    @dptr,a
                ljmp    prompt
 
                ; Process "DCD SOURCE/FORCE"
 
                ; Get a port number and assume own port if none given.
 
dcd_notdef:     mov     r3,a
                lcall   skipspc
                jz      dcd_myport
                lcall   getport
                jz      dcd_exit
                sjmp    dcd_gotport
dcd_myport:     mov     a,myport
dcd_gotport:    mov     r0,a
 
                ; Check that the port is one of the 4 for which the DTR/DCD
                ; output can be controlled.
 
                clr     c
                subb    a,#5
                jnc     dcd_toohigh
                cjne    r3,#1,notsource
 
                ; "DCD SOURCE ..." - set the port's bit in the DTR/DCD mask.
 
                mov     a,#8
dcd_loop1:      rl      a
                djnz    r0,dcd_loop1
                orl     a,dtr_mask_and
                sjmp    dcd_storemask
 
                ; "DCD FORCE ..." - reset the bit.
 
notsource:      mov     a,#0f7h
dcd_loop2:      rl      a
                djnz    r0,dcd_loop2
                anl     a,dtr_mask_and
 
                ; Store the updated mask.
 
dcd_storemask:  mov     dtr_mask_and,a
                ljmp    prompt
 
                ; Error exits (shared with the "DTR" command, next).
 
dcd_incomplete: mov     dptr,#inc_str
                sjmp    dcd_printit
dcd_toohigh:    mov     dptr,#dcderrmsg
                sjmp    dcd_printit
dcd_syntax:     mov     dptr,#syntax_str
dcd_printit:    lcall   prtstr
dcd_exit:       ljmp    prompt
 
dcdcmdtbl:      db      'SOURCE',0,'FORCE',0,'DEFAULT',0
dcderrmsg:      db      'DCD not controllable for this port.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  dtr_cmd
;
; Description:
;    This function provides the processing for the "dtr" command.  It sets
;    the timeout for which the DTR/DCD input of a port can be deasserted before
;    the port's connections are cleared.  Alternatively, it can set DTR/DCD to
;    be completely ignored for a given port.
;
; Command syntax: DTR TIMEOUT <seconds> [<port>]
;                 DTR IGNORE [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
                ; The DTR command may only be used from maintenance mode.
 
dtr_cmd:        lcall   checkmaint
                jnz     dcd_exit
 
                ; Get the "TIMEOUT" or "IGNORE" keyword.
 
                lcall   skipspc
                jz      dcd_incomplete
                mov     dptr,#dtrcmdtbl
                lcall   matchtoken
                jz      dcd_syntax
 
                ; Assume a timeout of 0 seconds (meaning, ignore DTR/DCD).
 
                mov     r4,#0
                cjne    a,#2,dtr_ignore
 
                ; Command was "DTR TIMEOUT ..."
 
                ; Get the timeout value and exit if illegal.
 
                lcall   skipspc
                jz      dcd_incomplete
                mov     r2,#' '
                lcall   getnum
                jb      badflag,dcd_exit
                mov     a,r1
                jz      toolow
                mov     r4,a
 
                ; Continue here for both versions of the command.  Get the
                ; port number and assume own port if not given.
 
dtr_ignore:     lcall   skipspc
                jz      dtr_myport
                lcall   getport
                jz      dcd_exit
                sjmp    dtr_gotport
dtr_myport:     mov     a,myport
 
                ; Store the timeout value in the DTR timeout table.
 
dtr_gotport:    dec     a
                add     a,#dtrtimtbl-256*(dtrtimtbl/256)
                mov     dpl,a
                clr     a
                addc    a,#dtrtimtbl/256
                mov     dph,a
                mov     a,r4
                movx    @dptr,a
                ljmp    prompt
 
dtrcmdtbl:      db      'IGNORE',0,'TIMEOUT',0,0
 
 
;---------------------------------------------------------------------------
; Function:  break_cmd
;
; Description:
;    This function provides the processing for the "break" command.  It sets
;    the minimum length an RS-232 "break" has to be before being recognized.
;    Alternatively, it can set breaks to be ignored on a given port.
;
; Command syntax: BREAK TIMEOUT <time / 10 ms> [<port>]
;                 BREAK IGNORE [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
                ; This command may only be used from maintenance mode.
 
break_cmd:      lcall   checkmaint
                jnz     bcmd_exit
 
                ; Check for the "TIMEOUT/IGNORE" keyword and exit if absent
                ; or invalid.
 
                lcall   skipspc
                jnz     bcmd_ok
bcmd_inc:       mov     dptr,#inc_str
                lcall   prtstr
                ljmp    prompt
bcmd_ok:        mov     dptr,#dtrcmdtbl
                lcall   matchtoken
                jz      bcmd_syntax
 
                ; Assume a break timeout of 0 (breaks ignored).
 
                mov     r3,#0
                cjne    a,#2,bcmd_gottime
 
                ; Command is "BREAK TIMEOUT ..."
 
                ; Get timeout value and complain if absent or invalid.
 
                lcall   skipspc
                jz      bcmd_inc
                mov     r2,#' '
                lcall   getnum
                jb      badflag,bcmd_exit
                mov     a,r1
                mov     r3,a
                jz      toolow
 
                ; Get the port number.  Assume own port if not given.
 
bcmd_gottime:   lcall   skipspc
                jz      bcmd_myport
                lcall   getport
                sjmp    bcmd_gotport
bcmd_myport:    mov     a,myport
 
                ; Store the timeout value in the break timeout table.
 
bcmd_gotport:   dec     a
                add     a,#brktimtbl-256*(brktimtbl/256)
                mov     dpl,a
                clr     a
                addc    a,#brktimtbl/256
                mov     dph,a
                mov     a,r3
                movx    @dptr,a
 
bcmd_exit:      ljmp    prompt
 
                ; Error exits.
 
toolow:         mov     dptr,#toolowstr
                lcall   prtstr
                ljmp    prompt
 
bcmd_syntax:    mov     dptr,#syntax_str
                lcall   prtstr
                ljmp    prompt
 
toolowstr:      db      'Invalid timeout.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  list_cmd
;
; Description:
;    This function provides the processing for the "list" command.  It shows
;    all current port settings and status information.
;
; Command syntax: LIST
;
; Inputs:   None
; Outputs:  Listing of information on the terminal.
;
 
                ; Print the header and underline it.
 
list_cmd:       mov     dptr,#listhead
                lcall   prtstr
                mov     r0,#52
lhloop:         mov     a,#'-'
                lcall   putchar
                djnz    r0,lhloop
                lcall   crlf
 
                ; Start the loop counter at port 1, and retrieve the DTR/DCD
                ; source/force bit mask.
 
                mov     r3,#1
                mov     a,dtr_mask_and
                swap    a
                mov     r4,a
 
                ; Loop:  Print the current port number.
 
listloop:       mov     r1,#' '
                mov     r2,#2
                mov     a,r3
                lcall   printnum
 
                ; Print an asterisk if the port is the current command port,
                ; a minus sign if the port is the first on the break queue,
                ; and a space otherwise.
 
                mov     a,#3
                lcall   tab
                mov     a,r3
                cjne    a,myport,l_notmyport
                mov     a,#'*'
                sjmp    l_printstar
l_notmyport:    mov     dptr,#brkqueue
                movx    a,@dptr
                cjne    a,3,l_notwaiting
                mov     a,#'-'
                sjmp    l_printstar
l_notwaiting:   mov     a,#' '
l_printstar:    lcall   putchar
 
                ; Print the port name.
 
                mov     a,r3
                mov     b,#9
                mul     ab
                mov     dptr,#nametbl-9
                add     a,dpl
                mov     dpl,a
                jnc     nocarry2
                inc     dph
nocarry2:       lcall   prtstr
 
                ; Print the most recently used baud rate.
 
                mov     a,#14
                lcall   tab
                mov     a,r3
                mov     b,#7
                mul     ab
                mov     dptr,#baudtbl-7
                add     a,dpl
                mov     dpl,a
                jnc     nocarry3
                inc     dph
nocarry3:       movx    a,@dptr
                lcall   showbaud
 
                ; If connected, print the port number this port is listening
                ; to, otherwise print a minus sign.
 
                mov     a,#21
                lcall   tab
                mov     dptr,#c_sourcetbl-1
                mov     a,r3
                movc    a,@a+dptr
                cjne    a,#15,connected
                mov     a,#' '
                lcall   putchar
                mov     a,#'-'
                lcall   putchar
                sjmp    conndone
 
connected:      mov     r1,#' '
                mov     r2,#2
                lcall   printnum
 
                ; If connected, also print the owner of the connection.
 
                mov     a,#25
                lcall   tab
                mov     dptr,#c_owntbl-1
                mov     a,r3
                movc    a,@a+dptr
                mov     r1,#' '
                mov     r2,#2
                lcall   printnum
 
                ; Print the break timeout, or a minus sign if zero.
 
conndone:       mov     a,#29
                lcall   tab
                mov     a,r3
                mov     dptr,#brktimtbl-1
                movc    a,@a+dptr
                jnz     brk_printasnum
                mov     dptr,#timblankstr
                lcall   prtstr
                sjmp    brk_done
brk_printasnum: mov     r1,#' '
                mov     r2,#3
                lcall   printnum
 
                ; If the port is one of the 4 for which the DTR/DCD output
                ; can be controlled, print "S" or "1", and the default.
 
brk_done:       mov     a,#33
                lcall   tab
                mov     a,r3
                clr     c
                subb    a,#5
                jnc     dtr_done
 
                ; Shift one bit out of the DTR source/force mask.
 
                mov     a,r4
                rrc     a
                mov     r4,a
                jc      dtr_source
                mov     a,#'1'
                sjmp    print_def
dtr_source:     mov     a,#'S'
print_dtr:      lcall   putchar
                mov     a,#35
                lcall   tab
                mov     a,r3
                mov     dptr,#dtrdeftbl-1
                movc    a,@a+dptr
                rrc     a
                clr     a
                addc    a,#'0'
print_def:      lcall   putchar
 
                ; Display the most recently seen state of the DTR/DCD input
                ; for this port.
 
dtr_done:       mov     a,#37
                lcall   tab
                mov     a,r3
                mov     dptr,#dtrcnttbl-1
                movc    a,@a+dptr
                jz      havedtr
                mov     a,#'0'
                sjmp    prtdtr
havedtr:        mov     a,#'1'
prtdtr:         lcall   putchar
 
                ; Display the DTR/DCD timeout, or "-" if DTR/DCD is being
                ; ignored for this port.
 
                mov     a,#39
                lcall   tab
                mov     a,r3
                mov     dptr,#dtrtimtbl-1
                movc    a,@a+dptr
                jnz     dtr_printasnum
                mov     dptr,#timblankstr
                lcall   prtstr
                sjmp    dtr_done2
dtr_printasnum: mov     r1,#' '
                mov     r2,#3
                lcall   printnum
 
                ; If the port is set to restricted mode, print "R", and
                ; the port access mask in hex.
 
dtr_done2:      mov     a,r3
                mov     dptr,#restrictbl-1
                movc    a,@a+dptr
                jz      r_done
 
                mov     a,#43
                lcall   tab
                mov     a,#'R'
                lcall   putchar
                mov     a,#' '
                lcall   putchar
                mov     a,r3
                lcall   maskaddr
                inc     dptr
                movx    a,@dptr
                lcall   printhex2
 
                ; Print the autoconnect for this port, if any.
 
r_done:         mov     dptr,#autoconntbl-1
                mov     a,r3
                movc    a,@a+dptr
                jz      ac_done
                mov     r5,a
                mov     a,#49
                lcall   tab
                mov     a,r5
                mov     r1,#' '
                mov     r2,#2
                lcall   printnum
 
                ; Loop until all ports done.
 
ac_done:        lcall   crlf
                inc     r3
                cjne    r3,#maxport+1,listloop_jmp
                ljmp    prompt
listloop_jmp:   ljmp    listloop
 
                ; Subroutine to display a baud rate.
 
showbaud:       mov     dptr,#baudnametbl
                dec     a
                jz      showit
                mov     r0,a
sloop:          movx    a,@dptr
                inc     dptr
                cjne    a,#0,sloop
                djnz    r0,sloop
showit:         ljmp    prtstr
 
                ; Text strings.
 
listhead:       db      'P#  NAME      BAUD  CONN OWN BRK DCD DTR   REST AUTO'
                db      13,10,0
 
timblankstr:    db      '  -',0
 
 
;---------------------------------------------------------------------------
; Function:  baud_cmd
;
; Description:
;    This function provides the processing for the "baud" command.  It sets
;    the baud rate to be used for the rest of the command session.  If a
;    port number is specified, it sets the default baud rate for that port.
;
; Command syntax: BAUD <baud rate> [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
                ; Get the baud rate from the command line and exit if not
                ; valid.
 
baud_cmd:       lcall   skipspc
                jnz     cmd_ok
                ljmp    inc_cmd
cmd_ok:         mov     dptr,#baudnametbl
                lcall   matchtoken
                jz      badbaud
                mov     r3,a
 
                ; Get the port number, assume own port if not given.
 
                lcall   skipspc
                jz      notport
                lcall   getport
                jz      baudret
                sjmp    checkport
notport:        mov     a,myport
 
                ; If the port is the current command port, then change the
                ; baud rate used to communicate with it.
 
checkport:      cjne    a,myport,notmybaud
                push    acc
                mov     a,r3
                lcall   setbaud
                pop     acc
 
                ; Either way, move the baud rate to the head of the list
                ; for the given port.
 
notmybaud:      lcall   fixtbl
                ljmp    prompt
 
                ; Error exit.
 
badbaud:        mov     dptr,#baudmsg
                lcall   prtstr
baudret:        ljmp    prompt
 
                ; Baud rate match table.
 
baudnametbl:    db      '110',0,'300',0,'1200',0,'2400',0,'4800',0,'9600',0
                db      '19200',0,0
 
                ; Error message.
 
baudmsg:        db      'Invalid or unsupported baud rate.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  name_cmd
;
; Description:
;    This function provides the processing for the "name" command.  It lets
;    a symbolic name to be associated with a given port.  It can also display
;    the name presently associated with a port.
;
; Command syntax: NAME <port> [<new name>]
;
; Inputs:   Taken from the command line
; Outputs:  Current name printed on the terminal if requested.
;
 
                ; This command can only be used from maintenance mode.
 
name_cmd:       lcall   checkmaint
                jnz     name_exit
 
                ; Get the port number and exit if not present or invalid.
 
                lcall   skipspc
                jz      inc_cmd
                lcall   getport
                jz      name_exit
 
                ; Compute address of name table entry for this port.
 
                dec     a
                mov     b,#9
                mul     ab
                mov     dptr,#nametbl
                add     a,dpl
                mov     dpl,a
                jnc     nocarry
                inc     dph
 
                ; If a name is not provided on the command line, just display
                ; the entry from the name table and exit.
 
nocarry:        lcall   skipspc
                jnz     setname
                lcall   prtstr
                lcall   crlf
name_exit:      ljmp    prompt
 
                ; Copy the name from the command line to the name table until
                ; at most 8 characters are copied.  Print a warning message
                ; if it was necessary to truncate the name.
 
setname:        mov     r3,#8
                mov     p2,#bufpage
setloop:        movx    a,@r0
                jz      namedone
                cjne    a,#' ',validchar
 
                ; Zero-terminate the name table entry, and pad it out with
                ; CTRL-A so the token matcher can be used on the table.
 
namedone:       clr     a
                movx    @dptr,a
                inc     a
setpad:         inc     dptr
                movx    @dptr,a
                djnz    r3,setpad
                ljmp    prompt
 
                ; Convert a character to uppercase and put it into the name
                ; table.  Continue until maximum number of characters copied.
 
validchar:      lcall   toupper
                movx    @dptr,a
                inc     dptr
                inc     r0
                djnz    r3,setloop
                clr     a
                movx    @dptr,a
 
                ; Get one more character from the command line.  If not zero
                ; or space, warn that the name was truncated.
 
                movx    a,@r0
                jz      setdone
                clr     c
                subb    a,#' '
                jz      setdone
                mov     dptr,#truncstr
                lcall   prtstr
setdone:        ljmp    prompt
 
                ; Error exit.
 
inc_cmd:        mov     dptr,#inc_str
                lcall   prtstr
                ljmp    prompt
 
truncstr:       db      'Name truncated to 8 characters.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  date_cmd
;
; Description:
;    This function provides the processing for the "date" command.  It allows
;    the display or modification of the current time/date.  The user must be
;    in maintenance mode to change the date.
;
; Command syntax: DATE [<YY/MM/DD HH:MM:SS>]
;
; Inputs:   Taken from the command line
; Outputs:  Current date if requested.
;
 
                ; See if any arguments follow the command.
 
date_cmd:       lcall   skipspc
                jnz     set_date
                ljmp    display_date
 
                ; Arguments follow.  Check that we are in maintenance mode.
 
set_date:       lcall   checkmaint
                jnz     setdone
 
                ; Get the year
 
                mov     r2,#'/'
                lcall   getnum
                jb      badflag,set_exit
                mov     a,r1
                clr     c
                subb    a,#80
                jnc     not_2000
                mov     a,#100
                add     a,r1
                mov     r1,a
not_2000:       mov     year_copy,r1
 
                ; Get the month
 
                mov     r2,#'/'
                lcall   getnum
                jb      badflag,set_exit
                mov     a,r1
                jz      baddate
                mov     month_copy,a
                clr     c
                subb    a,#13
                jnc     baddate
 
                ; Get the day
 
                mov     r2,#' '
                lcall   getnum
                jb      badflag,set_exit
                mov     a,r1
                jz      baddate
                mov     a,month_copy
                lcall   daysthismonth
                clr     c
                subb    a,r1
                jc      baddate
                mov     day_copy,r1
 
                ; Get the hour
 
                lcall   skipspc
                mov     r2,#':'
                lcall   getnum
                jb      badflag,set_exit
                mov     a,r1
                mov     hours_copy,a
                clr     c
                subb    a,#24
                jnc     baddate
 
                ; Get the minute
 
                mov     r2,#':'
                lcall   getnum
                jb      badflag,set_exit
                mov     a,r1
                mov     minutes_copy,a
                clr     c
                subb    a,#60
                jnc     baddate
 
                ; Get the second
 
                mov     r2,#' '
                lcall   getnum
                jb      badflag,set_exit
                mov     a,r1
                mov     seconds_copy,a
                clr     c
                subb    a,#60
                jnc     baddate
                lcall   skipspc
                jnz     baddate
 
                ; Request that the clock be updated, and wait until it is done.
 
                setb    date_set_flag
set_wait:       jb      date_set_flag,set_wait
                ljmp    prompt
 
                ; Error exit
 
baddate:        mov     dptr,#invalidmsg
                lcall   prtstr
set_exit:       ljmp    prompt
 
                ; Continue here to display the date.  First, request that the
                ; clock be read, and wait until it is done.
 
display_date:   setb    date_get_flag
wait_date:      jb      date_get_flag,wait_date
 
                ; Get the year, convert to 4-digit format, and print it.
 
                mov     a,year_copy
                mov     b,#100
                div     ab
                add     a,#19
                push    b
                lcall   prt2dig
                pop     acc
                lcall   prt2dig
 
                ; Print "/", and the month.
 
                mov     a,#'/'
                lcall   putchar
                mov     a,month_copy
                lcall   prt2dig
 
                ; Print "/", and the day.
 
                mov     a,#'/'
                lcall   putchar
                mov     a,day_copy
                lcall   prt2dig
 
                ; Print a space, and the hour.
 
                mov     a,#' '
                lcall   putchar
                mov     a,hours_copy
                lcall   prt2dig
 
                ; Print ":", and the minute.
 
                mov     a,#':'
                lcall   putchar
                mov     a,minutes_copy
                lcall   prt2dig
 
                ; Print ":", the second, CRLF, and exit.
 
                mov     a,#':'
                lcall   putchar
                mov     a,seconds_copy
                lcall   prt2dig
                lcall   crlf
                ljmp    prompt
 
                ; Subroutine to print a number as 2 digits.
 
prt2dig:        mov     r1,#'0'
                mov     r2,#2
                ljmp    printnum
 
                ; Error message.
 
invalidmsg:     db      'Invalid date/time entered.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  mode_cmd
;
; Description:
;    This function provides the processing for the "mode" command.  It sets
;    the default access level of a port to either "restricted" or "normal".
;
; Command syntax: MODE NORMAL [<port>]
;                 MODE RESTRICT [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
mode_cmd:       lcall   checkmaint
                jnz     mode_exit
                lcall   skipspc
                jz      mode_syntax
                mov     dptr,#modetbl
                lcall   matchtoken
                jz      mode_syntax
                mov     r3,a
                lcall   skipspc
                jnz     mode_getport
                mov     a,myport
                sjmp    mode_gotport
mode_getport:   lcall   getport
                jz      mode_exit
mode_gotport:   dec     a
                add     a,#restrictbl-256*(restrictbl/256)
                mov     dpl,a
                clr     a
                addc    a,#restrictbl/256
                mov     dph,a
                mov     a,r3
                dec     a
                movx    @dptr,a
                ljmp    prompt
 
mode_syntax:    mov     dptr,#syntax_str
                lcall   prtstr
mode_exit:      ljmp    prompt
 
modetbl:        db      'NORMAL',0,'RESTRICT',0,0
 
dl_cmd:         lcall   checkmaint
                jnz     dl_exit
                lcall   skipspc
                jz      dl_doit
                mov     dptr,#syntax_str
                lcall   prtstr
                ljmp    prompt
dl_doit:        lcall   download
dl_exit:        ljmp    prompt
 
 
run_cmd:        lcall   checkmaint
                jnz     run_exit
                lcall   skipspc
                jnz     run_getaddr
                mov     dptr,#inc_str
                lcall   prtstr
                ljmp    prompt
run_getaddr:    mov     r2,#' '
                lcall   gethex
                jb      badflag,run_exit
 
                ; Now call the address that was entered as a subroutine.
 
                clr     a
                mov     dph,r3
                mov     dpl,r4
                call    run_doit
run_exit:       ljmp    prompt
run_doit:       jmp     @a+dptr
 
 
;---------------------------------------------------------------------------
; Function:  mask_cmd
;
; Description:
;    This function provides the processing for the "mask" command.  It sets
;    the set of ports which are accessible to a port in restricted mode.
;
; Command syntax: MASK <mask in hex> [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
                ; This command can only be used in maintenance mode.
 
mask_cmd:       lcall   checkmaint
                jnz     mask_exit
 
                ; Get the mask and exit if missing or invalid.
 
                lcall   skipspc
                jnz     mask_getmask
                mov     dptr,#inc_str
                lcall   prtstr
                ljmp    prompt
mask_getmask:   mov     r2,#' '
                lcall   gethex
                jb      badflag,mask_exit
 
                ; Check that the mask is between 1 and 3FH, inclusive (6 bits).
 
                cjne    r3,#0,mask_invalid
                mov     a,r4
                anl     a,#0c0h
                jnz     mask_invalid
 
                ; Get the port number, and assume own port if not given.
 
                lcall   skipspc
                jnz     mask_getport
                mov     a,myport
                sjmp    mask_gotport
mask_getport:   lcall   getport
                jz      mask_exit
 
                ; Compute the address of the mask, and store the mask.
 
mask_gotport:   lcall   maskaddr
                mov     a,r3
                movx    @dptr,a
                inc     dptr
                mov     a,r4
                movx    @dptr,a
                inc     dptr
mask_exit:      ljmp    prompt
 
                ; Error exit.
 
mask_invalid:   mov     dptr,#invmaskstr
                lcall   prtstr
                ljmp    prompt
 
invmaskstr:     db      'Invalid mask.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  auto_cmd
;
; Description:
;    This function provides the processing for the "auto" command.  It sets
;    the port, if any, which a port should connect to when its DTR/DCD input
;    is asserted.
;
; Command syntax: AUTO <dest port> [<port>]
;                 AUTO OFF [<port>]
;
; Inputs:   Taken from the command line
; Outputs:  None
;
 
                ; This command can only be used from maintenance mode.
 
auto_cmd:       lcall   checkmaint
                jnz     auto_done
 
                ; Check if the keyword "OFF" is the next thing on the command
                ; line.  Exit if the rest of the line is empty.
 
                lcall   skipspc
                jnz     auto_getdest
                mov     dptr,#inc_str
                lcall   prtstr
                ljmp    prompt
auto_getdest:   mov     dptr,#autocmdtbl
                lcall   matchtoken
                jnz     gotoff
 
                ; If not "OFF", it must be a port number.  Get it and exit if
                ; invalid.
 
                lcall   getport
                jz      auto_done
                sjmp    gotdest
gotoff:         clr     a
gotdest:        mov     r5,a
                lcall   skipspc
 
                ; Get the port number, assume own port if not given.
 
                jnz     auto_getport
                mov     a,myport
                sjmp    auto_gotport
auto_getport:   lcall   getport
                jz      auto_done
 
                ; Store the port number (or zero for no autoconnect) in the
                ; table.
 
auto_gotport:   dec     a
                add     a,#autoconntbl-256*(autoconntbl/256)
                mov     dpl,a
                clr     a
                addc    a,#autoconntbl/256
                mov     dph,a
                mov     a,r5
                movx    @dptr,a
auto_done:      ljmp    prompt
 
                ; Table for the token matcher.
 
autocmdtbl:     db      'OFF',0,0
 
                ; Error messages (used by many commands).
 
inc_str:        db      'Incomplete command.',13,10,0
syntax_str:     db      'Syntax error.',13,10,0
 
 
;---------------------------------------------------------------------------
; Function:  help_cmd
;
; Description:
;    This function provides the processing for the "help" command.  It
;    displays a summary of all the switch commands on the terminal.
;    Maintenance commands are only shown if the user is in maintenance mode.
;
; Command syntax: HELP
;                 ?
;
; Inputs:   None
; Outputs:  None
;
 
help_cmd:       mov     dptr,#userhelptbl
                lcall   prtstr
                jnb     maintflag,help_done
                mov     dptr,#mainthelptbl
                lcall   prtstr
help_done:      ljmp    prompt
 
                ; Help for user commands.
 
userhelptbl:    db 13,10
                db 'USER COMMANDS:',13,10,13,10
                db 'Bye                                     '
                db 'Help',13,10
                db 'BAud 110|300|1200|2400|4800|9600|19200  '
                db 'List',13,10
                db 'Call <port>                             '
                db 'LInk <dest port> <source port>',13,10
                db 'CLear                                   '
                db 'Off',13,10
                db 'Date                                    '
                db 'Unlink <port>',13,10,13,10
                db 'ACCESS LEVEL COMMANDS:',13,10,13,10
                db 'Maint                                   '
                db 'Restrict',13,10
                db 'Normal',13,10,13,10,0
 
                ; Help for maintenance commands.
 
mainthelptbl:   db 'MAINTENANCE COMMANDS:',13,10,13,10
                db 'Autoconnect Off [<port>]                '
                db 'DCd Source [<port>]',13,10
                db 'Autoconnect <dest port> [<port>]        '
                db 'DTr Ignore [<port>]',13,10
                db 'BReak Ignore [<port>]                   '
                db 'DTr Timeout <time in seconds> [<port>]',13,10
                db 'BReak Timeout <time/10 ms> [<port>]     '
                db 'MASk <hex value> [<port>]',13,10
                db 'Date <YY/MM/DD HH:MM:SS>                '
                db 'MOde Normal [<port>]',13,10
                db 'DCd Default 0|1 [<port>]                '
                db 'MOde Restrict [<port>]',13,10
                db 'DCd Force [<port>]                      '
                db 'NAme <port> [<new name>]',13,10,13,10,0
 
                end